//  home   //  advanced search   //  news   //  categories   //  sql build chart   //  downloads   //  statistics
 ASP FAQ 
Home
ASP FAQ Tutorials

   8000XXXX Errors
   Alerts
   ASP.NET 2.0
   Classic ASP 1.0
      COM / ActiveX Components
      Forms
      General Topics
      Date/Time Routines
      Email Scripts & Info
      Files/Directories & FSO
   Databases
   General Concepts
   Search Engine Optimization (SEO)

Contact Us
Site Map

Search

Web
aspfaq.com
tutorials.aspfaq.com
classicasp.aspfaq.com

ASP FAQ Tutorials :: Classic ASP 1.0 :: General Topics :: How do I read the contents of a remote web page?


How do I read the contents of a remote web page?

You can include static txt and HTML files from remote servers by using a component (such as AspHTTP, ASPTear 1.50, or VB's built in InetCtrls) to parse the remote URL's content. 
 
You can also try this method out; it was tested with the MSXML objects which are installed with Windows 2000. You should make sure you have the latest versions of MSXML and XML Core Services (see MSXML Downloads). If you download the newer version, take special note of the new ProgID you should be using -- MSXML 4.0 now supports side-by-side installation, which means the ProgID below will actually use the older version. 
 
<% 
    url = "http://www.espn.com/main.html" 
    set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP") 
    xmlhttp.open "GET", url, false 
    xmlhttp.send "" 
    Response.write xmlhttp.responseText 
    set xmlhttp = nothing 
%>
 
And here it is in JavaScript: 
 
<script language=javascript runat=server> 
    var url = "http://www.espn.com/main.html"; 
    var xmlhttp = new ActiveXObject("MSXML2.ServerXMLHTTP"); 
    xmlhttp.open("GET", url, 0); 
    xmlhttp.send(""); 
    Response.Write(xmlhttp.responseText); 
    var xmlhttp = null; 
</script>
 
If you use a URL that doesn't exist, or you are behind a firewall that blocks certain web sites, or the site is behind a firewall that blocks traffic to port 80 / 443, or you are using a proxy server, or the site requires authentication, you will receive this error: 
 
msxml4.dll (0x80072EE7) 
Server name or address could not be resolved
 
To correct, you will have to figure out which of the issue(s) is standing in your way, and discuss workarounds with your or their network administrator(s). 
 
Don't forget that if your remote page has relative image URLs, or style sheets, or JavaScript files, or frames, or links, it won't work perfectly when ported to your server(s). To overcome this, you'll want to add a BASE HREF tag to keep all the images coming from the correct location. For example, the above code (which gets all the text from espn.com, but is formatted weird and doesn't function 100% as intended), is modified only slightly to work correctly: 
 
<% 
    url = "http://www.espn.com/main.html" 
 
    ' add a BASE HREF tag 
    Response.write "<BASE HREF='" & url & "'>" 
 
    set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP") 
    xmlhttp.open "GET", url, false 
    xmlhttp.send "" 
    Response.write xmlhttp.responseText 
    set xmlhttp = nothing 
%>
 
For information on increasing or decreasing the time allowed for the XMLHTTP objects to retrieve a response from a remote server, see Article #2407
 
If you need to POST data you can so by adding a header that tells the receiver you're sending FORM data: 
 
<% 
    url = "http://www.espn.com/main.html" 
    set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP") 
    xmlhttp.open "POST", url, false 
    xmlhttp.setRequestHeader "Content-Type", "application/x-www-form-urlencoded" 
    xmlhttp.send "x=1&y=2" 
    Response.write xmlhttp.responseText 
    set xmlhttp = nothing 
%>
 
Another thing you may want to do, going back to the original script, is make sure the server is there! If not, you can display a message... and you can customize it to display whether the server was not found at all, or if the server was found but you got a bad response (e.g. a 404 Page Not Found). Note that if you do not need to parse the content of the remote web page, that using the HEAD method here is far more efficient than using GET or POST... since only the headers are retrieved from the remote server, not any of the content. 
 
<%  
    ' deliberate typo:  
    url = "http://www.espn.co/main.html"  
 
    set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP")  
    on error resume next  
    xmlhttp.open "HEAD", url, false  
    xmlhttp.send ""  
    status = xmlhttp.status 
    if err.number <> 0 or status <> 200 then 
        if status = 404 then 
            Response.Write "Page does not exist (404)." 
        elseif status >= 401 and status < 402 then 
            Response.Write "Access denied (401)." 
        elseif status >= 500 and status <= 600 then 
            Response.Write "500 Internal Server Error on remote site." 
        else 
            Response.write "Server is down or does not exist." 
        end if 
    else  
        Response.Write "Server is up and URL is available."  
    end if  
    set xmlhttp = nothing  
%>
 
You might want to parse the results, instead of sending them straight to the client: 
 
<% 
    url = "http://www.espn.com/main.html"  
    set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP")  
    on error resume next 
    xmlhttp.open "GET", url, false 
    xmlhttp.send ""  
    if err.number <> 0 then 
        response.write "Url not found" 
    else 
        if instr(xmlhttp.responseText,"Stanley Cup")>0 then 
            response.write "There's a story about the playoffs." 
            response.write "<a href=" & url & ">Go there</a>?" 
        else 
            response.write "There is no story about the playoffs." 
        end if 
    end if 
    set xmlhttp = nothing 
%>
 
You may be interested in performing an asynchronous request, e.g. hitting an ASP page that acts like a batch file that gets fired but does not need to return any results. You can simply change the third parameter of the open call to TRUE (and leave out the reference to the responseText value): 
 
<% 
    url = "http://www.espn.com/main.html" 
    set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP") 
    xmlhttp.open "GET", url, true 
    xmlhttp.send "" 
    set xmlhttp = nothing 
%>
 
Finally, you may want to spoof your user agent, since the MSXML object sends something like "Mozilla/4.0 (compatible; Win32; WinHttp.WinHttpRequest.5)" -- many sites will view this as a spider or 'screen scraper', and for various reasons, might present alternate content -- here are two samples: 
 
<% 
    url = "http://www.espn.com/main.html"  
 
 
    ' this sample posts as the actual browser being used: 
 
 
    br = Request.ServerVariables("HTTP_USER_AGENT") 
    set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP")  
    on error resume next 
    xmlhttp.open "GET", url, false 
    xmlhttp.setRequestHeader "User-Agent",br 
    xmlhttp.send ""  
    if err.number <> 0 then 
        response.write "Url not found" 
    else 
        response.write xmlhttp.responseText 
    end if 
    set xmlhttp = nothing 
 
 
 
    ' this sample posts as "My funky browser." 
 
 
    set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP")  
    on error resume next 
    xmlhttp.open "GET", url, false 
    xmlhttp.setRequestHeader "User-Agent","My funky browser." 
    xmlhttp.send ""  
    if err.number <> 0 then 
        response.write "Url not found" 
    else 
        response.write xmlhttp.responseText 
    end if 
    set xmlhttp = nothing 
%>
 

 
If you encounter errors... you can use ParseError to determine the problem. 
 
<% 
    set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP")  
    ' ... stuff ... 
    on error resume next 
    xmlhttp.send ""  
    if err.number <> 0 then 
        response.write "Error: " & xmlhttp.parseError.URL & _ 
            "<br>" & xmlhttp.parseError.Reason 
        response.end 
    end if 
    ' ... stuff ... 
%>
 
A common error you might receive: 
 
msxml3.dll error '80072efd'  
A connection with the server could not be established
 
Make sure that the URL is actually reachable. You may have spelled the domain name wrong, or the site may actually be down. 
 
Test using a browser from that machine, or simply running a tracert / ping. Note that ping won't always return results, because many sites block all such traffic (mainly to help eliminate DOS attacks). However, ping should at least let you know the IP address, which means that the domain name was resolved correctly through DNS. Otherwise, it might be that your DNS server is preventing connection.

Related Articles

Can I bypass the ten connection limitation in Workstation / Professional?
Can I compact / repair an Access database from ASP code?
Can I create an array's size dynamically?
Can I detect the presence of ActiveX controls, like Flash, from ASP?
Can I dictate the load order of files on the client from ASP?
Can I have optional parameters to my subs / functions?
Can I host multiple sites in 2000 Workstation or XP Professional (e.g. PWS)?
Can I mimic trim / ltrim / rtrim in JScript?
Can I perform simple encryption / decryption in ASP?
Can I run IIS 5.0 / ASP 3.0 on Windows NT 4.0 or Windows 9x?
Can I run IIS on Windows Millennium or Windows XP Home?
Can I use IP address to uniquely identify visitors?
Does order matter when using different languages in ASP?
How can I give them a better 404 message?
How can I stop Photoshop from opening ASP files?
How can I track when my site is added to a user's favorites?
How do I access all active sessions on the server?
How do I access my server's registry from an ASP page?
How do I change a list into a set of table rows and columns?
How do I change document names / extensions in IIS / PWS?
How do I change the default server scripting language in InterDev?
How do I cloak / hide URL and QueryString information?
How do I comment blocks of ASP code?
How do I control access to an area?
How do I control printing from ASP?
How do I convert a name to proper case?
How do I convert exchange rates in ASP?
How do I convert from Hex to Int and back?
How do I convert numbers into words?
How do I convert old IDC / HTX pages to ASP?
How do I count the number of current users / sessions?
How do I count the number of times x occurs in string y?
How do I create a database from ASP?
How do I create my own blog?
How do I deal with disappearing application variables?
How do I decode an encoded URL?
How do I detect ENABLED cookies / javascript?
How do I detect the browser's encryption level / cipher strength?
How do I determine which version of IIS / ASP I'm running?
How do I disable the back/forward buttons?
How do I display the Euro symbol (€) in my ASP pages?
How do I embed a TAB character into source code?
How do I embed apostrophes (') and quotes (") in an HTML string?
How do I embed ASP delimiters (<% or %>) in a string?
How do I estimate the total size of my web page?
How do I execute a DOS command / batch file / exe from ASP?
How do I execute a ping command from ASP, and retrieve the results?
How do I find out the amount of space left on my server?
How do I fix the ::$DATA bug?
How do I FTP files from ASP?
How do I generate a treeview from ASP?
How do I generate unique GUIDs from ASP?
How do I get all the UBound() values in a multi-dimensional array?
How do I get IntelliSense to see ASP 3.0 methods?
How do I get my visitors' login name / username?
How do I get screen resolution from ASP?
How do I get the computer name / IP address of the server?
How do I get the server's timezone information?
How do I get the user's IP address or browser information?
How do I highlight words in a string?
How do I host multiple web sites on one IIS box?
How do I increase timeout values?
How do I iterate through session variables?
How do I know which version of VBScript my server is running?
How do I log / track ASP errors on my web site?
How do I make hyperlinks out of plain text URLs and e-mail addresses?
How do I make JavaScript send values to ASP?
How do I make my ASP page pause or 'sleep'?
How do I make my ASP page refresh?
How do I make my ASP pages more efficient?
How do I make search engines index pages with QueryStrings?
How do I make sure an entered string contains only valid characters?
How do I make sure my ASP question gets answered?
How do I make sure my servers have the same time?
How do I make sure people go to page x before page y?
How do I make sure the client is still connected before processing?
How do I make Visual InterDev's debugging features work?
How do I manage a session across multiple windows?
How do I pad digits with leading zeros?
How do I parse / analyze IIS Logs?
How do I parse the domain name out of a URL?
How do I parse the file name out of a path or URL?
How do I perform a Whois / DNS lookup from ASP?
How do I persist session state without cookies / session variables?
How do I prevent 'Invalid use of Null' errors?
How do I prevent my ASP pages from caching?
How do I prevent people from printing my ASP page?
How do I print the first n characters of a large block of text?
How do I prompt a "Save As" dialog for an accepted mime type?
How do I protect my ASP code?
How do I protect my client-side JavaScript code?
How do I protect my images and other visual content?
How do I put my ASP application onto a CD-Rom?
How do I read the event log from ASP?
How do I redirect an http:// request to https://?
How do I refresh global.asa without restarting the application?
How do I round a number *properly* with VBScript?
How do I run ASP on other web servers besides IIS?
How do I schedule ASP files?
How do I send a MsgBox or InputBox from ASP?
How do I set session variables from client-side script?
How do I show a "Please Wait..." message?
How do I solve 'Event ID 5' errors?
How do I solve 'The Requested Resource is in Use' errors?
How do I solve 'The server failed to load the application' errors?
How do I solve 'The specified procedure could not be found' errors?
How do I solve ASP 0115 errors?
How do I specify ByRef / ByVal in VBScript?
How do I stress test my ASP application?
How do I time my ASP code?
How do I turn a KB Article #, like Q191987, into a usable URL?
How do I use ASP to [...]
How do I use extensions other than .ASP for ASP files?
How do I warn people when their session is about to expire?
How do I zip / unzip files from ASP?
I called Session.Abandon, why are my session variables still there?
I have plenty of RAM, why do I get an 'Out of memory' error?
Is there an easier way to patch my server(s)?
Should I use ADOVBS.inc for declaring constants?
Should I use sessionID to uniquely identify users?
Should I use the .inc extension for my include files?
Should I use VBScript or JScript for ASP?
What do I do when IIS 5.0 will not start?
What do I need to know about Response.Redirect?
What is Event ID 36, and how can I get IIS running again?
What is this 'Cannot detect OS type' error with NT 4.0 Option Pack?
What is this error 'An unhandled data type was encountered'?
What is wrong with IsNumeric()?
What is wrong with Request.ServerVariables("HTTP_REFERER")?
What is wrong with Session_OnEnd()?
What kind of object is Response.Crackers?
What's the deal with IIS 5.0 and ASP 3.0?
When I run a page in my browser, why does the ASP code not execute?
Where can I find out about .NET?
Where can I find out about running Perl in IIS?
Where can I host ASP pages for free (or at least cheap)?
Where do I get IIS / ASP?
Where else can I learn about ASP?
Which editor should I use for developing ASP applications?
Which is better, rs(0) or rs("column_name")?
Why am I getting 'subscript out of range' errors?
Why am I having problems installing Visual Studio.NET RTM?
Why am I having problems with Server.Execute and/or Server.Transfer?
Why are people telling me to fix my clock / timezone?
Why can't I browse localhost without an Internet connection?
Why can't I grab custom headers from Request.ServerVariables()?
Why can't I pass querystring information AND links to #bookmarks?
Why can't I turn buffering off using Response.Buffer?
Why can't I use #EXEC or #ECHO in an ASP page?
Why do I get 'BOF or EOF' errors?
Why do I get 'HTTP 500-12 Application Restarting' errors?
Why do I get 'HTTP/1.0 Invalid Application Name' errors?
Why do I get 'Invalid Default Script Language' errors?
Why do I get 'Name redefined' errors?
Why do I get 'Object doesn't support this property or method' errors?
Why do I get 'The RPC Server is Unavailable' messages?
Why do I get 'Type Mismatch' when using the Session object?
Why do I get 8000FFFF / 8002802B errors?
Why do I get 80010105 errors?
Why do I get 80010108 errors?
Why do I get 80020003 errors?
Why do I get 80020005 errors?
Why do I get 80020009 errors?
Why do I get 8002000E errors?
Why do I get 80029c84 errors?
Why do I get 8004E00F errors?
Why do I get 80070034 / 80070035 errors?
Why do I get 80070056 errors?
Why do I get 80070057 errors?
Why do I get 80090016 errors?
Why do I get 800A01C2 errors?
Why do I get 800A01C9 errors?
Why do I get 800A01CA errors?
Why do I get 800A01F4 errors?
Why do I get 800A01F9 errors?
Why do I get 800A03EC errors?
Why do I get 800A03ED / 800A03EE errors?
Why do I get 800A03F6 errors?
Why do I get 800A0401 errors?
Why do I get 800A0408 errors?
Why do I get 800A0414 errors?
Why do I get 800A138F errors?
Why do I get a 500 Internal Server error for all ASP errors?
Why do I get an 'overflow' error using CInt?
Why do I get an error about a 'Smart HTML interpreter'?
Why do I get ASP 0101 errors?
Why do I get ASP 0113 / Script timed out errors?
Why do I get ASP 0130 / ASP 0131 errors?
Why do I get ASP 0138 errors?
Why do I get ASP 0158 errors?
Why do I get errors in the 800A0001 -> 800A000F range?
Why do I get errors in the 800A0030 -> 800A003A range?
Why do I get errors in the 800A03F1 -> 800A03FF range?
Why do I get errors in the 800A0400 -> 800A041F range?
Why do I get errors when trying to redirect?
Why do I get HTTP/1.1 400 Bad Request errors?
Why do I get non-database-related 80004005 errors?
Why do I get script errors on one machine but not another?
Why do I get the error Object Required: ''?
Why do my session / application variables disappear?
Why does 3.2 + 1.5 = 4.7000000000000002?
Why does 4 / 5 = 0?
Why does global.asa not fire?
Why does GUID not work correctly with response.write?
Why does IIS hang and/or stop serving ASP pages?
Why does my page render (properly) in IE and not in Netscape?
Why does RecordCount return as -1?
Why does REMOTE_HOST return an IP address instead of a name address?
Why does session.abandon not take effect right away?
Why is Netscape slow in IIS 5.0?
Why won't my ASP pages work in IIS 6.0?
Why won't my session variables stick?
Why won't QueryString values work with Server.Execute / Server.Transfer?
Why won't Windows search ASP files?
DllHost.Exe

 

 


Created: 9/20/2000 | Last Updated: 3/17/2005 | broken links | helpful | not helpful | statistics
© Copyright 2006, UBR, Inc. All Rights Reserved. (460)

 

Copyright 1999-2006, All rights reserved.
Finding content
Finding content.  An error has occured...