Can I get CDO messages to return a read receipt?

Here is some code that will set up a read receipt with CDO.Message:

<%
' since this doesn't *have* to match the from address
receiptTo = "you@yourdomain.com"

Set cdoConfig = CreateObject("CDO.Configuration")
Set cdoMessage = CreateObject("CDO.Message")

With cdoConfig.Fields
.Item(cdoSendUsingMethod) = cdoSendUsingPort
.Item(cdoSMTPServer) = "smtp.yourdomain.com"
.Update
End With

With cdoMessage
.Fields(cdoDispositionNotificationTo) = receiptTo
.Fields(cdoReturnReceiptTo) = receiptTo
.Fields.Update

Set .Configuration = cdoConfig

.From = "you@yourdomain.com"
.To = "them@theirdomain.com"
.Subject = "Sample CDO Message"
.TextBody = "This is a test for CDO.message"
.Send
End With

Set cdoMessage = Nothing
Set cdoConfig = Nothing
%>

Keep in mind that this won't necessarily tell you that the user has actually read and understood the message, only that they've opened it; and, also, that both Outlook and Outlook Express (and perhaps other clients as well) support the ability to turn off read receipts (either per instance or globally).

If you want to know about delivery in the event that a read receipt will never come, you can add a delivery status notification option of 4 (success) just before calling the .send method:

<%
'...
.DSNOptions = 4
.Send
'...
%>

Note that this will send a message to you that has no subject and no from address, and a large cryptic body telling you that the message was delivered successfully. There is a good chance your mail server, or anti-spam programs, will mark it as spam. So, test it out in your environment before assuming it will work...

Previously, this article had stated that the technique did not work. Ironically, all of my test e-mails were sent to mailboxes that had the "never send a read receipt" option enabled. Hey, you get what you pay for here. <G>



// home // advanced search // news // categories // sql build chart // downloads // statistics
ASP FAQ

Can I get CDO messages to return a read receipt?

Related Articles